home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / TVCHAN.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-29  |  4.7 KB  |  196 lines
  1. 10  'TVCHAN - Harmonic Frequencies - 16 MAY 96 rev. 28 SEP 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  COMMON EX$
  4. 40  CLS:KEY OFF
  5. 50  COLOR 7,0,1
  6. 60  UL$=STRING$(80,205)
  7. 70  U1$="##"
  8. 80  U2$="##########.###"
  9. 90  U3$="######,###.###"
  10. 100  X$=STRING$(80,32)
  11. 110  DIM C(69,4)    'TV channels
  12. 120  DIM F(15,2)    'amateur bands
  13. 130  DATA      1.800,2.000,        3.500,4.000,         7.000,7.300
  14. 140  DATA      10.100,10.150,      14.000,14.350,       18.086,18.168
  15. 150  DATA      21.000,21.450,      24.890,24.990,       28.000,29.700
  16. 160  DATA      50.000,54.000,      144.000,148.000,     220.000,225.000
  17. 170  DATA      420.000,450.000,    902.000,928.000,     1240,1300
  18. 180   FOR Z=1 TO 15:FOR Y=1 TO 2
  19. 190   READ F(Z,Y)
  20. 200   NEXT Y:NEXT Z
  21. 210  '
  22. 220  COLOR 15,2
  23. 230  PRINT " TV CHANNELS ( North America )";TAB(57)"by George Murphy VE3ERP ";
  24. 240  COLOR 1,0:PRINT STRING$(80,223);
  25. 250  COLOR 7,0
  26. 260  '
  27. 270  '.....start
  28. 280  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  29. 290  FLAG=0
  30. 300  GOSUB 1550   'preface
  31. 310  PRINT UL$;
  32. 320  COLOR 0,7:LOCATE ,24
  33. 330  PRINT " Press 1 to continue or 0 to EXIT "
  34. 340  COLOR 7,0
  35. 350  Z$=INKEY$:IF Z$=""THEN 350
  36. 360  IF Z$="0"THEN CLS:RUN EX$
  37. 370  IF Z$="1"THEN 400
  38. 380  GOTO 350
  39. 390  '
  40. 400  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  41. 410  SCAN=0
  42. 420  PRINT " Press number in < > to:
  43. 430  PRINT UL$;
  44. 440  PRINT "   <2> Display frequencies for a specific TV channel"
  45. 450  PRINT "   <3> Scan all TV channels for ham band harmonics"
  46. 460  PRINT "   <4> Display TVI harmonics of any signal"
  47. 470  Z$=INKEY$:IF Z$=""THEN 470
  48. 480  IF Z$="2"THEN ALL=0:GOTO 530
  49. 490  IF Z$="3"THEN ALL=1:GOTO 570
  50. 500  IF Z$="4"THEN 1180
  51. 510  GOTO 470
  52. 520  '
  53. 530  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  54. 540  INPUT " ENTER: T.V.Channel Number ( 2-69 ).........";CH
  55. 550  IF CH<2 OR CH>69 THEN BEEP:GOTO 530
  56. 560  '
  57. 570  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  58. 580  PRINT TAB(12)"Channel";TAB(32)"Bandwidth";TAB(55)"Video";TAB(69)"Audio"
  59. 590  PRINT TAB(14)"No.";TAB(28)"MHz    to     MHz";TAB(56)"MHz";TAB(70);"MHz"
  60. 600  PRINT UL$;
  61. 610  IF ALL=0 THEN 650
  62. 620     FOR SCAN=2 TO 69
  63. 630     CH=SCAN:GOTO 650
  64. 640  '
  65. 650  VIEW PRINT 6 TO 24:CLS:VIEW PRINT:LOCATE 6
  66. 660  CH=INT(CH)
  67. 670  N=48
  68. 680    FOR Z=2 TO 69
  69. 690  IF Z=5 THEN N=70
  70. 700  IF Z=7 THEN N=168
  71. 710  IF Z=14 THEN N=464
  72. 720  N=N+6
  73. 730  C(Z,1)=N
  74. 740  C(Z,2)=N+6
  75. 750  C(Z,3)=N+1.25
  76. 760  C(Z,4)=N+5.75
  77. 770    NEXT Z
  78. 780  '
  79. 790  '.....screen print
  80. 800  K$=" UHF":IF CH<14 THEN K$=" VHF"
  81. 810  COLOR 0,7:LOCATE ,11:PRINT K$;USING "### ";CH;
  82. 820  FOR Z=1 TO 4:PRINT USING U2$;C(CH,Z);:NEXT Z
  83. 830  COLOR 7,0
  84. 840  PRINT UL$;
  85. 850  COLOR 0,7
  86. 860  LOCATE CSRLIN-1,22:PRINT " The frequencies shown above are the: "
  87. 870  COLOR 7,0
  88. 880  '
  89. 890  '......harmonics
  90. 900  FOR Z=1 TO 4:H(Z)=C(CH,Z):NEXT Z
  91. 910  FLAG=0
  92. 920    FOR Z=2 TO 10
  93. 930  N$="th "
  94. 940  IF Z=2 THEN N$="nd "
  95. 950  IF Z=3 THEN N$="rd "
  96. 960  FOR Y=1 TO 4:H(Y)=H(Y)/2:NEXT Y
  97. 970  PRINT USING "###";Z;:PRINT N$;"harmonic of";TAB(19);
  98. 980  FOR X=1 TO 4:Y=H(X):GOSUB 1120:PRINT USING U2$;Y;:COLOR 7,0:NEXT X
  99. 990  PRINT ""
  100. 1000    NEXT Z
  101. 1010  IF FLAG=0 THEN 1060
  102. 1020  PRINT UL$;
  103. 1030  COLOR 15,1:LOCATE ,15
  104. 1040  PRINT " Highlighted frequencies are in amateur radio bands "
  105. 1050  COLOR 7,0
  106. 1060  IF ALL=0 THEN 1780
  107. 1070  IF SCAN=69 THEN 1780
  108. 1080  IF FLAG=1 THEN GOSUB 1830
  109. 1090  NEXT SCAN
  110. 1100  END
  111. 1110  '
  112. 1120  '.....amateur bands
  113. 1130  FOR B=1 TO 15
  114. 1140  IF Y>=F(B,1)AND Y<=F(B,2)THEN COLOR 15,1:FLAG=1
  115. 1150  NEXT B
  116. 1160  RETURN
  117. 1170  '
  118. 1180  '.....TVI harmonics
  119. 1190  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3
  120. 1200  INPUT " ENTER: Frequency in MHz of transmitted signal.....";F
  121. 1210  LOCATE CSRLIN-1:PRINT X$;:LOCATE CSRLIN-1
  122. 1220  PRINT TAB(8)"Harmonic";TAB(33)"MHz";TAB(45)"TV CHannel ?"
  123. 1230  PRINT UL$;
  124. 1240  COLOR 0,7
  125. 1250  PRINT " TRANSMITTED SIGNAL...";USING U3$;F;:PRINT " "
  126. 1260  COLOR 7,0
  127. 1270  FOR Z=2 TO 19
  128. 1280  F=F*2
  129. 1290  N$="th "
  130. 1300  IF Z=2 THEN N$="nd "
  131. 1310  IF Z=3 THEN N$="rd "
  132. 1320  PRINT USING " ##";Z;:PRINT N$;" harmonic.......";
  133. 1330  PRINT USING U3$;F;
  134. 1340  GOSUB 1380
  135. 1350  NEXT Z
  136. 1360  GOTO 1780    'end
  137. 1370  '
  138. 1380   IF F=54 THEN H=2:GOTO 1520
  139. 1390  IF F>54 AND F<72 THEN K=7:GOTO 1510
  140. 1400   IF F=72 THEN H=4:GOTO 1520
  141. 1410   IF F=76 THEN H=5:GOTO 1520
  142. 1420  IF F>76 AND F<88 THEN K=7.66667:GOTO 1510
  143. 1430   IF F=88 THEN H=6:GOTO 1520
  144. 1440   IF F=174 THEN H=7:GOTO 1520
  145. 1450  IF F>174 AND F<216 THEN K=22:GOTO 1510
  146. 1460   IF F=216 THEN H=13:GOTO 1520
  147. 1470   IF F=470 THEN H=14:GOTO 1520
  148. 1480  IF F>470 AND F<806 THEN K=64.3333:GOTO 1510
  149. 1490   IF F=806 THEN H=69:GOTO 1520
  150. 1500  LOCATE ,48:PRINT "- no -":GOTO 1530
  151. 1510  H=INT(F/6-K)
  152. 1520  COLOR 0,7:LOCATE ,45:PRINT " Channel";H:COLOR 7,0
  153. 1530  RETURN
  154. 1540  '
  155. 1550  '.....preface
  156. 1560  T=9
  157. 1570  PRINT TAB(T);
  158. 1580  PRINT "In North America the following frequencies are reserved for"
  159. 1590  PRINT TAB(T);
  160. 1600  PRINT "commercial television broadcasting:"
  161. 1610  PRINT
  162. 1620  PRINT "                  54 MHz -  72 Mhz     VHF Channels  2 - 4"
  163. 1630  PRINT "                  76 MHz -  88 Mhz     VHF Channels  5 - 6"
  164. 1640  PRINT "                 174 MHz - 216 Mhz     VHF Channels  7 - 13"
  165. 1650  PRINT "                 470 MHz - 806 Mhz     UHF Channels 14 - 69"
  166. 1660  PRINT
  167. 1670  PRINT TAB(T);
  168. 1680  PRINT "This program lists the frequencies used by each channel, plus "
  169. 1690  PRINT TAB(T);
  170. 1700  PRINT "lower frequencies whose harmonics fall within the TV spectrum."
  171. 1710  PRINT
  172. 1720  PRINT TAB(T);
  173. 1730  PRINT "Where such frequencies are within any of the amateur radio bands,"
  174. 1740  PRINT TAB(T);
  175. 1750  PRINT "these frequencies are highlighted."
  176. 1760  RETURN
  177. 1770  '
  178. 1780  '.....end
  179. 1790  GOSUB 1830
  180. 1800  GOTO 270
  181. 1810  END
  182. 1820  '
  183. 1830  'HARDCOPY
  184. 1840  GOSUB 1950:LOCATE 25,2:COLOR 14,6
  185. 1850  PRINT " Press 1 to print screen, 2 to print screen & ";
  186. 1860  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  187. 1870  Z$=INKEY$:IF Z$="3"THEN GOSUB 1950:RETURN
  188. 1880  IF Z$="1"OR Z$="2"THEN GOSUB 1950:GOTO 1900
  189. 1890  GOTO 1870
  190. 1900  FOR QX=1 TO 24:FOR QY=1 TO 80
  191. 1910  LPRINT CHR$(SCREEN(QX,QY));
  192. 1920  NEXT QY:NEXT QX
  193. 1930  IF Z$="2"THEN LPRINT CHR$(12)
  194. 1940  GOTO 1840
  195. 1950  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  196.